RED引擎设置死亡复活回城

首先设置人物死亡回城的脚本在QF文件

我们找到脚本的QF查找死亡触发命令[@PLAYDIE]

在此命令触发行下添加触发条件

例如：

[@PLAYDIE]
#IF

;这里判断是否是假人
ISDUMMY
#ACT
#CALL [\假人制作\智能假人\死亡触发.txt] @假人死亡

#IF

;这里判断是否等级大于0
CHECKLEVELEX > 0
KILLBYHUM
#ACT
sendmsg 0 系统：玩家『<$USERNAME>』在[<$CURRENTMAPDESC>]被玩家『<$KILLER>』击毙，死相真惨不忍睹啊！
#ELSEACT
sendmsg 0 系统：玩家『<$USERNAME>』在<$CURRENTMAPDESC>(<$X>:<$Y>)，被凶猛的怪物【<$MONKILLER>】给弄死了!

#IF

;这里我们看到的444是个人标识，你可以认为它就是一个数字开关，1为开放，0为关闭
CHECK [444] 1
KILLBYHUM
#ACT

;这里就是我上面所说的数字开关被关闭
SET [444] 0

;这里呢用的是DELSKILL命令删除了玩家的力能
DELSKILL 半月弯刀
DEPRIVETITLE 狂暴之力
;这里是赋值给S0为杀害凶手【这里是S和零，属于S变量】
MOV S0 <$KILLER>
;然后这里就给凶手金币50000
S0.GIVE 金币 50000
;这里呢就给全局变量的全民积分加积分，
S0.LOADVAR HUMAN 全民血战积分 ..\..\..\..\钢琴制作\全民血战积分.TXT
S0.CALCVAR HUMAN 全民血战积分 + 1
S0.SAVEVAR HUMAN 全民血战积分 ..\..\..\..\钢琴制作\全民血战积分.TXT
ADDTEXTLIST ..\..\..\..\钢琴制作\全区喊话.TXT [击杀公告]:<$SERVERNAME>的勇士”<$USERNAME>”击杀了:『<$KILLER>』,当前总奖池≮<$GLOBAL(狂暴消费)>≯冰雪币！

#IF
#ACT
;这里我们看到没有条件，只是记录了被杀人物的名字和所在的区名
S0.ADDTEXTLIST ..\..\..\..\钢琴制作\当日人物名字血.TXT <$USERNAME>
S0.ADDTEXTLIST ..\..\..\..\钢琴制作\当日人物区字血.TXT <$SERVERNAME>
;然后这里就开始岩石跳转到复活命令行
delaygoto 1000 @复活

[@复活]
#IF
#ACT
;这里直接给了一个复活的命令
REALIVE
;然后给P7.P8赋了两个随机值，
MOVR P7 303 317
MOVR P8 325 335
;然后这个随机值被用到飞回土城的两个X和Y轴的坐标点
MAPMOVE 3 <$STR(P7)> <$STR(P8)>
;这里就给人物利用命令加血2000W
HUMANHP + 20000000
;这里呢给了一个顶戴花翎位置2关闭特效输出的一个命令
SETICON 2 -1
;同时呢开始检测人物的各项触发属性，因为人物死亡后狂暴被卸掉，所以狂暴封号的触发随之失效
#CALL [\钢琴制作\切割变量.TXT] @切割触发
#CALL [\钢琴制作\封号刷新.TXT] @封号NEW
#CALL [\钢琴制作\小怪切割.TXT] @小怪切割
SENDMSG 0 〖系统提示〗:玩家『<$USERNAME>』战死沙场、又回到了游戏！勇士们，再次起来战斗吧!!!

fanshi188永久赞助会员

打赏 收藏 海报 链接